home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / dassl / dpotrf.f < prev    next >
Text File  |  1996-07-19  |  6KB  |  187 lines
  1.       SUBROUTINE DPOTRF( UPLO, N, A, LDA, INFO )
  2. *
  3. *  -- LAPACK routine (version 1.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     February 29, 1992
  7. *
  8. *     .. Scalar Arguments ..
  9.       CHARACTER          UPLO
  10.       INTEGER            INFO, LDA, N
  11. *     ..
  12. *     .. Array Arguments ..
  13.       DOUBLE PRECISION   A( LDA, * )
  14. *     ..
  15. *
  16. *  Purpose
  17. *  =======
  18. *
  19. *  DPOTRF computes the Cholesky factorization of a real symmetric
  20. *  positive definite matrix A.
  21. *
  22. *  The factorization has the form
  23. *     A = U' * U ,  if UPLO = 'U', or
  24. *     A = L  * L',  if UPLO = 'L',
  25. *  where U is an upper triangular matrix and L is lower triangular.
  26. *
  27. *  This is the block version of the algorithm, calling Level 3 BLAS.
  28. *
  29. *  Arguments
  30. *  =========
  31. *
  32. *  UPLO    (input) CHARACTER*1
  33. *          Specifies whether the upper or lower triangular part of the
  34. *          symmetric matrix A is stored.
  35. *          = 'U':  Upper triangular
  36. *          = 'L':  Lower triangular
  37. *
  38. *  N       (input) INTEGER
  39. *          The order of the matrix A.  N >= 0.
  40. *
  41. *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
  42. *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
  43. *          n by n upper triangular part of A contains the upper
  44. *          triangular part of the matrix A, and the strictly lower
  45. *          triangular part of A is not referenced.  If UPLO = 'L', the
  46. *          leading n by n lower triangular part of A contains the lower
  47. *          triangular part of the matrix A, and the strictly upper
  48. *          triangular part of A is not referenced.
  49. *
  50. *          On exit, if INFO = 0, the factor U or L from the Cholesky
  51. *          factorization A = U'*U or A = L*L'.
  52. *
  53. *  LDA     (input) INTEGER
  54. *          The leading dimension of the array A.  LDA >= max(1,N).
  55. *
  56. *  INFO    (output) INTEGER
  57. *          = 0: successful exit
  58. *          < 0: if INFO = -k, the k-th argument had an illegal value
  59. *          > 0: if INFO = k, the leading minor of order k is not
  60. *               positive definite, and the factorization could not be
  61. *               completed.
  62. *
  63. *  =====================================================================
  64. *
  65. *     .. Parameters ..
  66.       DOUBLE PRECISION   ONE
  67.       PARAMETER          ( ONE = 1.0D+0 )
  68. *     ..
  69. *     .. Local Scalars ..
  70.       LOGICAL            UPPER
  71.       INTEGER            J, JB, NB
  72. *     ..
  73. *     .. External Functions ..
  74.       LOGICAL            LSAME
  75.       INTEGER            ILAENV
  76.       EXTERNAL           LSAME, ILAENV
  77. *     ..
  78. *     .. External Subroutines ..
  79.       EXTERNAL           DGEMM, DPOTF2, DSYRK, DTRSM, XERBLA
  80. *     ..
  81. *     .. Intrinsic Functions ..
  82.       INTRINSIC          MAX, MIN
  83. *     ..
  84. *     .. Executable Statements ..
  85. *
  86. *     Test the input parameters.
  87. *
  88.       INFO = 0
  89.       UPPER = LSAME( UPLO, 'U' )
  90.       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
  91.          INFO = -1
  92.       ELSE IF( N.LT.0 ) THEN
  93.          INFO = -2
  94.       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
  95.          INFO = -4
  96.       END IF
  97.       IF( INFO.NE.0 ) THEN
  98.          CALL XERBLA( 'DPOTRF', -INFO )
  99.          RETURN
  100.       END IF
  101. *
  102. *     Quick return if possible
  103. *
  104.       IF( N.EQ.0 )
  105.      $   RETURN
  106. *
  107. *     Determine the block size for this environment.
  108. *
  109.       NB = ILAENV( 1, 'DPOTRF', UPLO, N, -1, -1, -1 )
  110.       IF( NB.LE.1 .OR. NB.GE.N ) THEN
  111. *
  112. *        Use unblocked code.
  113. *
  114.          CALL DPOTF2( UPLO, N, A, LDA, INFO )
  115.       ELSE
  116. *
  117. *        Use blocked code.
  118. *
  119.          IF( UPPER ) THEN
  120. *
  121. *           Compute the Cholesky factorization A = U'*U.
  122. *
  123.             DO 10 J = 1, N, NB
  124. *
  125. *              Update and factorize the current diagonal block and test
  126. *              for non-positive-definiteness.
  127. *
  128.                JB = MIN( NB, N-J+1 )
  129.                CALL DSYRK( 'Upper', 'Transpose', JB, J-1, -ONE,
  130.      $                     A( 1, J ), LDA, ONE, A( J, J ), LDA )
  131.                CALL DPOTF2( 'Upper', JB, A( J, J ), LDA, INFO )
  132.                IF( INFO.NE.0 )
  133.      $            GO TO 30
  134.                IF( J+JB.LE.N ) THEN
  135. *
  136. *                 Compute the current block row.
  137. *
  138.                   CALL DGEMM( 'Transpose', 'No transpose', JB, N-J-JB+1,
  139.      $                        J-1, -ONE, A( 1, J ), LDA, A( 1, J+JB ),
  140.      $                        LDA, ONE, A( J, J+JB ), LDA )
  141.                   CALL DTRSM( 'Left', 'Upper', 'Transpose', 'Non-unit',
  142.      $                        JB, N-J-JB+1, ONE, A( J, J ), LDA,
  143.      $                        A( J, J+JB ), LDA )
  144.                END IF
  145.    10       CONTINUE
  146. *
  147.          ELSE
  148. *
  149. *           Compute the Cholesky factorization A = L*L'.
  150. *
  151.             DO 20 J = 1, N, NB
  152. *
  153. *              Update and factorize the current diagonal block and test
  154. *              for non-positive-definiteness.
  155. *
  156.                JB = MIN( NB, N-J+1 )
  157.                CALL DSYRK( 'Lower', 'No transpose', JB, J-1, -ONE,
  158.      $                     A( J, 1 ), LDA, ONE, A( J, J ), LDA )
  159.                CALL DPOTF2( 'Lower', JB, A( J, J ), LDA, INFO )
  160.                IF( INFO.NE.0 )
  161.      $            GO TO 30
  162.                IF( J+JB.LE.N ) THEN
  163. *
  164. *                 Compute the current block column.
  165. *
  166.                   CALL DGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
  167.      $                        J-1, -ONE, A( J+JB, 1 ), LDA, A( J, 1 ),
  168.      $                        LDA, ONE, A( J+JB, J ), LDA )
  169.                   CALL DTRSM( 'Right', 'Lower', 'Transpose', 'Non-unit',
  170.      $                        N-J-JB+1, JB, ONE, A( J, J ), LDA,
  171.      $                        A( J+JB, J ), LDA )
  172.                END IF
  173.    20       CONTINUE
  174.          END IF
  175.       END IF
  176.       GO TO 40
  177. *
  178.    30 CONTINUE
  179.       INFO = INFO + J - 1
  180. *
  181.    40 CONTINUE
  182.       RETURN
  183. *
  184. *     End of DPOTRF
  185. *
  186.       END
  187.